刚才在别的论坛看到的两个好看公式（通达信）
注：不懂什么叫未来函数，都不明白这个未来是什么东东，只用软件测出来就叫嚣者免用
苦海无边学为先
复制内容到剪贴板
代码:
STICKLINE(C,12,0,5,0),COLOR9C8700;
STICKLINE(C,-2,0,5,0),COLOR004400;
{DRAWGBK(C, COLORRGB(000,80,120), COLORRGB(250,250,250),1);
//弱态描述}
苦难众生:EMA((1-WINNER(C)),13)*10,COLOR008800;
苦海深渊:(C-MA(C,27))/MA(C,27)<-0.16,COLOR005500,LINETHICK0;
渐脱苦海:HHV(苦难众生,3)>苦难众生,COLOR0099DD,LINETHICK0;
STICKLINE(渐脱苦海,HHV(苦难众生,3),0,4,0),COLOR0099DD;
STICKLINE(苦难众生>0,苦难众生,0,4,0),COLOR555500;
STICKLINE(苦难众生>8.5,苦难众生,8.5,4,0),COLOR00BBAA;
STICKLINE(苦难众生>9,苦难众生,9,4,0),COLOR00FFAA;
STICKLINE(苦难众生>9.5,苦难众生,9.5,4,0),COLORFFFFFF;
涨二成仍套比:=(1-WINNER(1.2*C))*10;
涨二成五仍套比:=(1-WINNER(1.25*C))*10;
涨三成仍套比:=(1-WINNER(1.3*C))*10;
涨四成仍套比:=(1-WINNER(1.4*C))*10;
涨五成仍套比:=(1-WINNER(1.5*C))*10;
STICKLINE(涨二成仍套比,涨二成仍套比,0,4,0),COLOR66EE66;
STICKLINE(涨二成五仍套比,涨二成五仍套比,0,4,0),COLOR33AA33;
STICKLINE(涨三成仍套比,涨三成仍套比,0,4,0),COLOR007700;
STICKLINE(涨四成仍套比,涨四成仍套比,0,4,0),COLOR005500;
STICKLINE(涨五成仍套比,涨五成仍套比,0,4,0),COLOR003300;
{//大底判断}
换手:=VOL/CAPITAL*100;
综价:=(H+L+O+3*C)/6;
量权均线:=DMA(综价,换手/SUM(换手,10));
量价判底:=(C-量权均线)/量权均线<-0.22;
速跌:=REF(H,10)/C>1.382;
急跌:=REF(C,3)/L>1.15;
易涨:=COST(15)>1.25*C;
市场弱状:=速跌 AND 急跌 AND 易涨;
异动:=H>L*1.051 OR H>L+0.05*REF(C,1);
乖离条件:=(C-MA(C,34))/MA(C,34)<-0.23 OR C/MA(C,60)<0.74;
乖离判底:=(市场弱状 OR 乖离条件) AND 异动;
佛珠:量价判底 OR 乖离判底,COLORRED,LINETHICK0;
{//长线波动与短线波动的描述}
多空线:=(MA(综价,2)+MA(综价,4)+MA(综价,8)+MA(综价,16))/4;
长线多空对峙位:=(多空线-LLV(多空线,120))/(HHV(多空线,120)-LLV(多空线,120))*10;
K长:=SMA(长线多空对峙位,21,1);
D长:=SMA(K长,21,1);
J长:=3*K长-2*D长;
J长A:=IF(J长>10,10,J长);
J长B:=IF(J长A<0,0,J长A);
均J长B:=SMA(J长B,2,1);
虔心向佛:均J长B>=REF(均J长B,1),COLORFF63DB,LINETHICK0;
短线多空对峙位:=(多空线-LLV(多空线,30))/(HHV(多空线,30)-LLV(多空线,30))*10;
K短:=SMA(短线多空对峙位,3,1);
D短:=SMA(K短,3,1);
J短:=3*K短-2*D短;
J短A:=IF(J短>10,10,J短);
J短B:=IF(J短A<0,0,J短A);
均J短B:=SMA(J短B,2,1);
观音指点:CROSS(均J短B,REF(均J短B,1)) AND K短<8,COLORYELLOW,LINETHICK0;
福缘:均J短B>=REF(均J短B,1),COLORRED,LINETHICK0;
缘尽:NOT(福缘),COLORWHITE,LINETHICK0;
观音点化:CROSS(均J短B,苦难众生) AND 均J短B>REF(均J短B,1),COLORFFFFFF,LINETHICK0;
{//强势描述}
乖离13:=10-SMA((C-MA(C,13))/MA(C,13),2,1)*10;
乖离16:=10-SMA((C-MA(C,16))/MA(C,16),2,1)*10;
乖离21:=10-SMA((C-MA(C,21))/MA(C,21),2,1)*10;
可羽化:=乖离13<10;
羽化:可羽化 AND 乖离13<REF(乖离13,1),LINETHICK0,COLORFF76FF;
可飞升:=乖离16<10;
飞升:可飞升 AND 乖离16<REF(乖离16,1) AND 乖离16<乖离13,LINETHICK0,COLOR00389A;
可成仙:=乖离21<10;
成仙:乖离21<REF(乖离21,1) AND 可成仙 AND 乖离21<乖离16,LINETHICK0,COLOR00BEFF;
STICKLINE(可成仙,乖离21,10,4,0),COLOR00389A;
STICKLINE(成仙,乖离21,10,4,0),COLOR00BEFF;
STICKLINE(可飞升,乖离16,10,4,0),COLOR00389A;
STICKLINE(可羽化,乖离13,10,4,0),COLORFF76FF;
成佛:CROSS(均J短B,乖离21),COLOR0000FF,LINETHICK0;
DRAWICON(成佛,10,6);
DRAWICON(成佛,9.5,6);
DRAWICON(成佛,9.0,6);
{//画图}
STICKLINE(苦海深渊,0,0.8,10,0),COLOR001100;
DRAWICON(佛珠,1.5,5);
IF(虔心向佛,均J长B,DRAWNULL),COLOR990099,LINETHICK4,POINTDOT;
IF(NOT(虔心向佛),均J长B,DRAWNULL),COLOR888888,LINETHICK4,POINTDOT;
IF(福缘,均J短B,DRAWNULL),COLORRED,LINETHICK3;
IF(缘尽,均J短B,DRAWNULL),COLORWHITE,LINETHICK3;
DRAWICON(观音指点,REF(均J短B,1),11);
DRAWTEXT(成佛,10,'天界修炼'),COLORFFFFFF;
点化后周期:=BARSLAST(观音点化);
点化后C尽利:IF(点化后周期>0,(C-REF(C,点化后周期))/REF(C,点化后周期)-0.01,0),LINETHICK0,COLORYELLOW;
DRAWTEXT(观音点化,均J短B,'观音点化'),COLOR0000FF;
{//版权信息}
DRAWTEXT((CURRBARSCOUNT=15),10,'WHK-WXW编辑V8.0'){,ALIGN5},COLORFFFF00;修渡成佛
复制内容到剪贴板
代码:
{-----------------------☆功能开关------------------------}
STICKLINE(C,12,0,5,0),COLOR9C8700;
STICKLINE(C,-2,0,5,0),COLOR004400;
{套牢赢利}
短亏:EMA(10*(1-WINNER(1.38*C)),1),NODRAW,COLOR52FF78; {原参数:=1.1}
中亏:EMA(10*(1-WINNER(1.44*C)),1),NODRAW,COLORGREEN;{原参数:=1.2}
长亏:EMA(10*(1-WINNER(1.68*C)),1),NODRAW,COLOR00B900;{原参数:=1.5}
赢利:WINNER(C)*10,NODRAW,COLORWHITE;{//当日赢利盘}
{弱态描述}
R_S1:=EMA((1-WINNER(C)),13)*10; R_S2:=HHV(R_S1,3)>R_S1 AND R_S1>4;
{佛指}
QX1:=EMA(C,12); QX2:=SUM(V,5); QX3:=QX2/3; QX4:=QX3/CAPITAL;
QX5:=DMA(QX1,QX4); QX6:=REF(H,10); QX7:=QX6/C; QX8:=QX7>1.35;
QX9:=COST(20); QX10:=(QX9-C); QX11:=QX10/C; QX12:=QX11>0.15;
QX13:=H>L*1.051; QX14:=COUNT(QX13,5)>1; QX15:=QX13 AND QX14; QX16:=(C-QX5);
QX17:=QX16/QX5; QX18:=QX17*100<-30;
秋风扫落叶:=(QX18 OR QX8) AND QX12 AND QX15;
F_Z1:=(H+L+O+C*3)/6; F_Z2:=(EMA(F_Z1,2)+EMA(F_Z1,4)+EMA(F_Z1,8)+EMA(F_Z1,16))/4;
F_Z3:=(F_Z2-LLV(F_Z2,30))/(HHV(F_Z2,30)-LLV(F_Z2,30))*10; F_Z4:=SMA(F_Z3,3,1);
F_Z5:=SMA(F_Z4,3,1); F_Z6:=3*F_Z4-2*F_Z5; F_Z7:=IF(F_Z6>10,10,F_Z6);
F_Z8:=IF(F_Z7<0,0,F_Z7); F_Z9:=SMA(F_Z8,2,1);
修德:=CROSS(F_Z8,REF(F_Z9,1)) AND F_Z4<8;{//低吸}
善缘:F_Z8>=REF(F_Z8,1),COLORRED,NODRAW;
点化:=CROSS(F_Z9,R_S1) AND F_Z9>REF(F_Z9,1);{//追}
{强势描述}
乖离1:=10-SMA((C-MA(C,13))/MA(C,13),2,1)*10;{//乖离11}
乖离2:=10-SMA((C-MA(C,16))/MA(C,16),2,1)*10;{//乖离16}
乖离3:=10-SMA((C-MA(C,21))/MA(C,21),2,1)*10;{//乖离21}
Q_S1:=乖离1<10;
羽化:Q_S1 AND 乖离1<REF(乖离1,1),NODRAW,COLORFF76FF;
Q_S2:=乖离2<10;
Q_S3:=乖离3<10;
成仙:乖离3<REF(乖离3,1) AND Q_S3 AND 乖离3<乖离2,NODRAW,COLOR00BEFF;
成佛:=CROSS(F_Z9,乖离3);{//追涨}
苦海:NOT(善缘),NODRAW,,COLORFF8000;{//缘尽}
{-----------------【图解模板】---------------------}
{弱态描述}
STICKLINE(R_S2,HHV(R_S1,3),0,5,0),COLOR0099DD;
STICKLINE(R_S1>0,R_S1,0,5,0),COLOR004400;
STICKLINE(R_S1>8,R_S1,8,5,0),COLOR008888;
STICKLINE(R_S1>8.5,R_S1,8.5,5,0),COLOR00BB88;
STICKLINE(R_S1>9,R_S1,9,5,0),COLOR00FF88;
{强势描述}
STICKLINE(Q_S3,乖离3,10,5,0),COLOR00389A;
STICKLINE(成仙,乖离3,10,5,0),COLOR00BEFF;
STICKLINE(Q_S2,乖离2,10,5,0),COLOR00389A;
STICKLINE(Q_S1,乖离1,10,5,0),COLORFF76FF;
{套牢赢利}
STICKLINE(短亏>0,短亏,0,3,0),COLOR52FF78;
STICKLINE(中亏>0,中亏,0,2,0),COLOR00A600;
STICKLINE(长亏>0,长亏,0,3,0),COLOR005800;
{佛指}
IF(善缘,F_Z9,DRAWNULL),LINETHICK3,COLORRED;
IF(苦海,F_Z9,DRAWNULL),LINETHICK3,COLORFF5000;
DRAWICON(修德 AND F_Z9<4,REF(F_Z9,1),11);
DRAWTEXT(FILTER(修德 AND F_Z9<4,10),5,'施'),COLORFF9FFF;
DRAWTEXT(FILTER(修德 AND F_Z9<4,10),6,'德'),COLORFF9FFF;
DRAWICON(点化,F_Z9,10);
DRAWTEXT(点化,F_Z9,'行'),COLORBROWN;
DRAWTEXT(点化,F_Z9-1,'善'),COLORBROWN;
DRAWICON(成佛,F_Z9,12);
DRAWTEXT(成佛,F_Z9,'我'),COLORYELLOW;
DRAWTEXT(成佛,F_Z9-1,'不'),COLORYELLOW;
DRAWTEXT(成佛,F_Z9-2,'下'),COLORYELLOW;
DRAWTEXT(成佛,F_Z9-3,'地'),COLORYELLOW;
DRAWTEXT(成佛,F_Z9-4,'狱'),COLORYELLOW;
{DRAWTEXT(成佛,F_Z9-5,'谁'),COLORYELLOW;
DRAWTEXT(成佛,F_Z9-6,'下 '),COLORYELLOW;
DRAWTEXT(成佛,F_Z9-7,'地 '),COLORYELLOW;
DRAWTEXT(成佛,F_Z9-8,'狱'),COLORYELLOW;}
{VERTLINE(秋风扫落叶),LINEDOT,COLORBLACK;}
DRAWTEXT(FILTER(秋风扫落叶,5),7.5,'岸'),COLORYELLOW;{低点}
DRAWTEXT(FILTER(秋风扫落叶,5),9,'是'),COLORYELLOW;
DRAWTEXT(FILTER(秋风扫落叶,5),10.5,'头'),COLORYELLOW;
DRAWTEXT(FILTER(秋风扫落叶,5),12,'回'),COLORYELLOW;
